home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
17 Bit Software 6: Level 6
/
17 Bit - Level 6 (1998)(Epic Marketing)[!].iso
/
quartz
/
q0402.dms
/
q0402.adf
/
BootX5.23
/
Installer.script
< prev
Wrap
Text File
|
1992-12-29
|
5KB
|
241 lines
; $VER: Install BootX 2.00 (18.9.92)
;
; Installer script for BootX.
;
(set UserLevel.old @user-level)
; Initialize messages.
(set Language 3)
(set #WrongKickStart "\nYou must be using at least KickStart 2.04 to run this version of BootX.")
(set #CopyingReqTools "Copying ReqTools.library to Libs:")
(set #CopyingPowerPacker "Copying PowerPacker.library to Libs:")
(set #CopyingExplode "Copying Explode.library to Libs:")
(set #WhichLanguage "\nWhich languages should be installed ?\n")
(set #WhichLanguageHelp
(cat "\n"
"The Amiga can be operated in many different"
"languages. If you want BootX to use the same"
"language as the Amiga Workbench then a catalog"
"file must be copied to your system disk for"
"each language supported.\n"
"\n"
"To reduce the amount of space consumed by the"
"language files, you can select to have only the"
"files of specific languages copied.\n"
"\n"
"Simply check the boxes of the languages you wish"
"to have available on your system.\n"
"\n"
@askoptions-help
)
)
(procedure InstallLanguages
(
(set n 0)
(while (set language (select n "Dansk" "Deutsch" "English" "Français" "Italiano" "Nederlands" "Norsk" "Svenska" ""))
(
(if (in SelectedLanguages n)
(
(if (<> 2 n)
(
(makedir (cat "SYS:Locale/Catalogs/" language))
(copyfiles (source (cat "Locale/Catalogs/" language))
(dest (cat "SYS:Locale/Catalogs/" language))
(all))
))
))
(set n (+ n 1))
))
))
; Welcome the user.
(complete 0)
(welcome)
; Make sure we are running under KickStart 2.04.
(if (< (/ (getversion) 65536) 37)
(abort #WrongKickStart)
)
; Copy the BootX executable and support files.
(set Path.Source
(tackon
(askdir
(prompt "\nSelect the drawer where I can find the uninstalled BootX.\n")
(help @askdir-help)
(default (pathonly @icon))
)
""
)
)
(set Path.Dest
(tackon
(askdir
(prompt "\nSelect the drawer where you want the BootX program "
"and its support files to reside.\n")
(help @askdir-help)
(default "Work:Utilities")
)
""
)
)
(copyfiles
(prompt "\nSelect which files to install:\n")
(help @copyfiles-help)
(source Path.Source)
(dest Path.Dest)
(choices "BootX"
"BootX.Alarm"
"BootX.BBLib"
"BootX.Brain"
"BootX.Guide"
"BootX.Recog")
(infos)
(confirm)
)
(complete 70)
; Copy the BootX.doc and BootX.history files.
(if
(askbool
(prompt "\nDo you wish to install the BootX documentation ?")
(help @askbool_help)
(default 1)
)
(
(set Path.Doc
(tackon
(askdir
(prompt "\nSelect the drawer where you want the BootX "
"documentation to reside.\n")
(help @askdir-help)
(default Path.Dest)
)
""
)
)
(copyfiles
(prompt "\nSelect which files to install:\n")
(help @copyfiles-help)
(source Path.Source)
(dest Path.Doc)
(choices "BootX.doc"
"BootX.History"
"BootX.Recog.History")
(infos)
(confirm)
)
)
)
(complete 90)
; Copy the ReqTools library.
(message
"\n"
"BootX requires the ReqTools.library to run.\n"
"\n"
"Before I install it I'll check to see if you have already a "
"more recent version of the ReqTools.library.\n"
"If so, I will not overwrite it.\n"
)
(copylib
(prompt "\n" #CopyingReqTools)
(help @copylib-help)
(source "Libs/reqtools.library")
(dest "Libs:")
(confirm)
)
; Copy the PowerPacker library.
(message
"\n"
"BootX can load and save its external files using the "
"PowerPacker.library by Nico François\n"
"\n"
"Before I install it I'll check to see if you have already a "
"more recent version of the PowerPacker.library.\n"
"If so, I will not overwrite it.\n"
)
(copylib
(prompt "\n" #CopyingPowerPacker)
(help @copylib-help)
(source "Libs/powerpacker.library")
(dest "Libs:")
(confirm)
)
; Copy the Explode library.
(message
"\n"
"To decrunch and check Imploder crunched executables "
"BootX requires the Explode.library v6.0 or higher.\n"
"\n"
"Before I install it I'll check to see if you have already a "
"more recent version of the Explode.library.\n"
"If so, I will not overwrite it.\n"
)
(copylib
(prompt "\n" #CopyingExplode)
(help @copylib-help)
(source "Libs/explode.library")
(dest "Libs:")
(confirm)
)
(complete 100)
; Install the language catalogs (if running on WorkBench 2.1 or higher)
(if (exists "SYS:Locale/Catalogs")
(
(user 2)
(set SelectedLanguages
(askoptions
(prompt #WhichLanguage)
(help #WhichLanguageHelp)
(choices "Dansk"
"Deutsch"
"English"
; "Español"
"Français"
"Italiano"
"Nederlands"
"Norsk"
; "Português"
"Svenska")
(default 4)
))
(user UserLevel.old)
(InstallLanguages)
))
; Cleanup
(set @default_dest Path.Dest)
(exit)